[Synopsis-changes] Synopsis/Synopsis/tests configure.ac,NONE,1.1

[Stefan Seefeld]

Update of /cvs/synopsis/Synopsis/tests
In directory frida:/tmp/cvs-serv9641

Added Files:
	configure.ac 
Log Message:
support unit tests for C++ API

--- NEW FILE: configure.ac ---
dnl $Id: configure.ac,v 1.1 2004/01/12 20:24:46 stefan Exp $
dnl
dnl Copyright (C) 2003 Stefan Seefeld
dnl All rights reserved.
dnl Licensed to the public under the terms of the GNU LGPL (>= 2),
dnl see the file COPYING for details.
dnl

AC_PREREQ(2.56)
AC_REVISION($Revision: 1.1 $)
AC_INIT(tests, 1.0, synopsis-devel at fresco.org)

AC_ARG_WITH(python, 
  [  --with-python=PATH      specify the Python interpreter],
  PYTHON="$with_python",
  PYTHON=""
)

AC_PROG_CXX

if test -n "$PYTHON" -a "$PYTHON" != yes; then
  AC_CHECK_FILE($PYTHON,,AC_MSG_ERROR([Cannot find Python interpreter]))
else
  AC_PATH_PROG(PYTHON, python2 python, python)
fi
PYTHON_PREFIX=`$PYTHON -c "import sys; print sys.prefix"`
PYTHON_INCLUDE=`$PYTHON -c "from distutils import sysconfig; print sysconfig.get_python_inc()"`
PYTHON_VERSION=`$PYTHON -c "from distutils import sysconfig; print sysconfig.get_config_var('VERSION')"`
PYTHON_LIBS="-L $PYTHON_PREFIX/lib/python$PYTHON_VERSION/config -lpython$PYTHON_VERSION"
PYTHON_DEP_LIBS=`$PYTHON -c "from distutils import sysconfig; print sysconfig.get_config_var('LIBS') or ''"`

case `uname -s` in
CYGWIN*)
    if test `$PYTHON -c "import os; print os.name"` = posix; then
dnl Cygwin doesn't have an -lutil, but some versions of distutils tell us to use it anyway.
dnl It would be better to check for each library it tells us to use with AC_CHECK_LIB, but
dnl to do that, we need the name of a function in each one, so we'll just hack -lutil out 
dnl of the list.
      PYTHON_DEP_LIBS=`$PYTHON -c "from distutils import sysconfig; import re; print re.sub(r'\\s*-lutil', '', sysconfig.get_config_var('LIBS') or '')"`
    else dnl this is 'nt'
      if test "$CXX" = "g++"; then
        CXXFLAGS="-mno-cygwin $CXXFLAGS"
        LDFLAGS="-mno-cygwin $LDFLAGS"
      fi
      PYTHON_INCLUDE=`cygpath -a $PYTHON_INCLUDE`
      PYTHON_DEP_LIBS=`$PYTHON -c "from distutils import sysconfig; print sysconfig.get_config_var('LIBS') or ''"`
    fi
    ;;
*)
    ;;
esac

CPPFLAGS="-I $PYTHON_INCLUDE $CPPFLAGS"
LDFLAGS="-rdynamic $LDFLAGS"
LIBS="$LIBS $PYTHON_LIBS $PYTHON_DEP_LIBS"

AC_CONFIG_FILES([QMTest/configuration])

AC_OUTPUT